Quit

Kahler-Einstein metric on dP3 by constrained optimization

Charles Doran, Chris Herzog, Josh Kantor (U. Wash), Matthew Headrick (Stanford), Toby Wiseman (Imperial)

Copyright March 2007

This notebook computes the approximation to the Kahler-Einstein metric using constrained optmiziation as described by us in section 6 of hep-th/0703057.

The calculation below computes the approximation for 18th order polynomial expansions and some low lying eigenvalues transforming in the trivial representation of the dihedral group.

Notation differs from paper; x=(Subscript[x, 1]),y=(Subscript[x, 2])

We construct a power series solution in our symmetric variables U and V.

UVrels   =  {V  ->  
          x^2 y^2 (x + y)^2, 
U ->  
          x^2  +  x y  +  y^2}

gp[x_,  y_]  := 
      1/2 ( (1 - x) Log[1 - x]  + (1 + x) 
              Log[1 + x] +  (1 - y) Log[1 - y]  + (1 + y) 
              Log[1 + y]  +  (1 - (x + y)) 
              Log[1 - (x + y)]  +  (1 + x + y) 
              Log[1 + x + y])

MAeq[x_, y_, f_] :=( Derivative[2, 0][f][x, y]Derivative[0, 2][f][x, y]-(Derivative[1, 1][f][x, y])^2) -Exp[ 2 x Derivative[1, 0][f][x, y] + 2 y Derivative[0, 1][f][x, y] - 2  f[x, y]]

The coefficients of the U^n series will be Ai, of the V U^n series Bi, and so on.
We adopted a slightly different formula for A1 because it's easier to express the higher coefficients in terms of α than in terms of A1.

Solve[-1/2 Log[3]  - Log[α] == 
        A1,  α]

Aa =  {-1/2 Log[3]  - Log[α],  A1,  A2,  A3,  A4,  
        A5,  A6,  A7,  A8,  A9,  A10}

Bb  =  {B0,  B1,  B2,  B3,  B4,  B5,  B6,  B7}

Cc = {C0,  C1,  C2,  C3,  C4}

Dd  =  {D0,  D1}

hguessintermediate  =  (Sum[
              U^n Aa[[n + 1]],  {n, 0, 9}]  +  
            Sum[V U^n Bb[[n + 1]],  {n, 0, 6}] +  
            Sum[V^2  U^n Cc[[n + 1]],  {n, 0, 3}]  +  
            Sum[V^3 U^n Dd[[n + 1]],  {n, 0, 0}] ) /.  
        UVrels

hguess[x_,  y_]  =  hguessintermediate;

gguess[x_, y_]  :=  gp[x, y]  +  hguess[x, y]

myseries  =  
        CoefficientList[
          Normal[Series[
              MAeq[x, y, gguess]  /.  {x -> e x,  
                  y ->  e y}, {e, 0, 16}, {y, 0, 16}]], {e, 
            y}];

myseries[[1]]

A1rels  =  
      Solve[myseries[[1]] == 0,  Aa[[2]]]

A2rel  =  Solve[(myseries[[3]]  /.  
                A1rels[[2]])  == 0,  
          Aa[[3]]][[1]]

A3rel  =  Solve[
          Simplify[
              myseries[[5]]  /.  
                Join[A1rels[[2]],  A2rel]] == 0,  
          A3][[1]]

A4B1rel  =  Solve[(myseries[[7]]  /.  
                Join[A1rels[[2]],  A2rel,  A3rel]) == 
            0,  {A4,  B1}][[1]]

A5B2rel  =  Solve[(myseries[[9]]  /.  
                Join[A1rels[[2]],  A2rel,  A3rel,  
                  A4B1rel]) == 0,  {A5,  B2}][[1]]

A6B3rel  =  Solve[(myseries[[11]] /.  
                Join[A1rels[[2]],  A2rel,  A3rel,  A4B1rel,  
                  A5B2rel]) == 0,  {A6,  B3}][[1]]

A7B4C1rel  =  Solve[(myseries[[13]]  /.  
                Join[A1rels[[2]],  A2rel,  A3rel,  A4B1rel,  
                  A5B2rel,  A6B3rel]) == 0,  {A7,  B4, 
            C1}][[1]]

A8B5C2rel  =  Solve[(myseries[[15]]  /.  
                Join[A1rels[[2]],  A2rel,  A3rel,  A4B1rel,  
                  A5B2rel,  A6B3rel,  A7B4C1rel]) == 0,  {A8,  
            B5, C2}][[1]]

A9B6C3rel  =  Solve[(myseries[[17]]  /.  
                Join[A1rels[[2]],  A2rel,  A3rel,  A4B1rel,  
                  A5B2rel,  A6B3rel,  A7B4C1rel,  A8B5C2rel]) == 
            0,  {A9,  B6, C3}][[1]]

And that's the first 18 orders in the series expansion!

therels  =  
      Sort[Join[A1rels[[2]],  A2rel,  A3rel,  A4B1rel,  A5B2rel,  
          A6B3rel,  A7B4C1rel,  A8B5C2rel,  A9B6C3rel]]

gconstrained[x_,  y_]   =  
        Simplify[
          gguess[x, y]  /. 
            Join[ therels, { A10 -> 0,  B7 -> 0,  
                C4 -> 0,  D1 -> 0}]];

hconstrained[x_,  y_]   =  
        Simplify[
          hguess[x, y]  /. 
            Join[ therels, { A10 -> 0,  B7 -> 0,  
                C4 -> 0,  D1 -> 0}]];

mymin[y_] =1-2 y - 2 y^2 + (1 - y^2)(1 - (1 + y)^2)Derivative[0, 2][hconstrained][1, y]-Exp[-2 hconstrained[1, y] + 2Derivative[1, 0][hconstrained][1, y] + 2y Derivative[0, 1][hconstrained][1, y]];

bestfit  =  
      FindMinimum[
        Sum[mymin[j /10]^2, {j, -10, 0, 0.5}],  {{α, 
            0.77}, {B0,  0.005}, {C0,  0}, {D0,  0}}]

meritfigure  =  
      Sum[MAeq[i 0.099, j 0.099, gconstrained]^2  /.  
          bestfit[[2]],  {i, 0, 10}, {j, -10, 0}]

errorfit  =  
      Plot3D[(MAeq[x, y, gconstrained] /.  bestfit[[2]]),  {x, 0, 
          0.99}, {y, -0.99, 0},  PlotRange -> All,  
        Mesh -> False]

Okay, now we're on to calculating eigenvalues.

SP[x_,  y_]  =  
      gconstrained[x, y]  /.  bestfit[[2]]

v =  {x, y}

G  =  {{D[g[x, y], x, x],  D[g[x, y], x, y]}, {D[g[x, y], x, y],  
          D[g[x, y], y, y]}}

detG  =  
      D[g[x, y], x, x] D[g[x, y], y, y] - D[g[x, y], x, y]^2

myLap[x_, y_, 
        g_,  ψ_]  =  -Simplify[ 
          Sum[Inverse[G][[i]][[j]] D[ 
                  D[ψ[x, y],  v[[j]]] ,  v[[i]]],  {i, 1, 
                2},  {j, 1, 2}]  -  
            2 Sum[v[[i]] D[ψ[x, y], v[[i]]],  {i, 1, 
                  2}]]

psitest[x_,  y_]  =   0.1 + X1 (x^2  +  x y  +  y^2)  +  
        X2 (x^2  +  x y  +  y^2)^2  +  
        X3 (x^2  +  x y  +  y^2)^3  +  
        Y1 x^2 y^2 (x + y)^2

tomin[x_,  y_]  =  
        myLap[x, y, SP ,  psitest]  -  
          EV psitest[x, y];

Here's the first eigenvalue stored as EV -> 6.32235.

NMinimize[{Sum[
          tomin[i 0.09, j 0.09]^2,  {i, 0, 10}, {j, -10, 0}],  
        EV > 5},  {EV, X1,  X2,  X3,  Y1}]

NMinimize[{Sum[
          tomin[i 0.09, j 0.09]^2,  {i, 0, 10}, {j, -10, 0}],  
        EV > 12},  {EV, X1,  X2,  X3,  Y1}]

And the second stored as EV -> 17.2356

Here are the eigenvalues using the canonical metric -- a little lower.

tomin[x_,  y_]  =  
        myLap[x, y, gp ,  psitest]  -  
          EV psitest[x, y];

NMinimize[{Sum[
          tomin[i 0.09, j 0.09]^2,  {i, 0, 10}, {j, -10, 0}],  
        EV > 4},  {EV, X1,  X2,  X3,  Y1}]

NMinimize[{Sum[
          tomin[i 0.09, j 0.09]^2,  {i, 0, 10}, {j, -10, 0}],  
        EV > 12},  {EV, X1,  X2,  X3,  Y1}]